;----------------  Tiger1用 Ver.9 --------------------

;２サーボ（アンプ）コントロールプログラム
;サーボバラシアンプ使用時の補正付き
;３ｃｈ砲身上下サーボコントロール付き
;砲身上下スピード調整機能付き
;砲塔旋回用4ｃｈ出力付き
;砲塔旋回サーボ停止位置初期設定機能付き（EEPROMに保存）
;コンバットサウンドスイッチ付き
;ブローバックサーボコントロール付き
;大砲音＋車体の揺れ
;砲塔旋回スピードを固定（Ver.3）
;サーボの強制停止機能つき
;デモンストレーション動作つき
;コンバットサウンド一体型に対応
;RA4に大砲ＬＥＤ発光＆音のＳＷをRB7、切替をRB6に変更
;機銃のＬＥＤの点滅速度を調整可能に
;左右旋回値をデータ化(Ver.8)
;走行用アンプのセンター位置を記憶(Ver.9)
;左右旋回時の片側補正値を追加

;Ver9.2.0	2001.04.26	By T.HINOKI

		LIST		P=16C84,R=DEC
	PC	EQU	2
	STATUS	EQU	3
	PG	EQU	5
	PORTA	EQU	5
	PORTB	EQU	6
	EEDATA	EQU	8
	EEADR	EQU	9
	OPTION_REG	EQU	H'81'
	TRISA	EQU	H'85'
	TRISB	EQU	H'86'
	EECON1	EQU	H'88'
	EECON2	EQU	H'89'
	RD	EQU	0
	WR	EQU	1
	WREN	EQU	2
	COUNT1	EQU	H'10'
	COUNT2	EQU	H'11'
	PIN1	EQU	H'12'	;1ｃｈ入力パルス幅（左・右）
	PIN2	EQU	H'13'	;２ｃｈ入力パルス幅（前進・後進）
	PIN3	EQU	H'14'	;３ｃｈ入力パルス幅（砲身上下用）
	PIN4	EQU	H'15'	;４ｃｈ入力パルス幅（砲塔旋回用）

	POUT1	EQU	H'16'	;1ｃｈ出力パルス幅（左キャタ速度）
	POUT2	EQU	H'17'	;２ｃｈ出力パルス幅（右キャタ速度）
	POUT3	EQU	H'18'	;３ｃｈ出力パルス幅（砲身上下用）
	POUT4	EQU	H'19'	;４ｃｈ出力パルス幅（砲塔旋回用）
	POUT5	EQU	H'20'	;５ｃｈ出力パルス幅（ブローバックサーボ用）

	KEISAN1	EQU	H'1A'	;計算用変数
	KEISAN2	EQU	H'1B'	;計算用変数
	KEISAN3	EQU	H'1C'	;計算用変数
	HSPEED	EQU	H'1D'	;砲身の上下スピード
	COUNT3	EQU	H'1E'	;砲身の上下スピード作業用
	CENTER3	EQU	H'1F'	;砲塔旋回サーボ停止位置
	COUNT4	EQU	H'21'	;ブローバックサーボの動作カウント用
	COUNT10	EQU	H'22'	;長時間のウエイト用
	COUNT11	EQU	H'23'	;ＴＯＰスピードの時間（揺れに使用）
	COUNT9	EQU	H'24'	;デモ走行作業用
	COUNT8	EQU	H'25'	;機銃発光のタイミング
	CENTER1	EQU	H'26'	;走行用アンプのセンター位置(左)
	CENTER2	EQU	H'27'	;走行用アンプのセンター位置(右)
	SOKUDO	EQU	H'28'	;旋回時の速度ＵＰ値

	ORG	0
	GOTO	START
;------------------------減速ＤＡＴＡ---------------------
	ORG	3
SSOKUDO
	ADDWF	PC,1	;X.Y
	RETLW	4	;0.0
	RETLW	3	;0.1
	RETLW	3	;0.2
	RETLW	2	;0.3
	RETLW	2	;0.4
	RETLW	1	;0.5
	RETLW	1	;0.6
	RETLW	0	;0.7
	RETLW	0	;0.8
	RETLW	0	;0.9
	RETLW	7	;1.0
	RETLW	6	;1.1
	RETLW	5	;1.2
	RETLW	4	;1.3
	RETLW	3	;1.4
	RETLW	2	;1.5
	RETLW	1	;1.6
	RETLW	0	;1.7
	RETLW	0	;1.8
	RETLW	0	;1.9
	RETLW	14	;2.0
	RETLW	12	;2.1
	RETLW	10	;2.2
	RETLW	8	;2.3
	RETLW	6	;2.4
	RETLW	4	;2.5
	RETLW	2	;2.6
	RETLW	0	;2.7
	RETLW	0	;2.8
	RETLW	0	;2.9
	RETLW	21	;3.0
	RETLW	18	;3.1
	RETLW	15	;3.2
	RETLW	12	;3.3
	RETLW	9	;3.4
	RETLW	6	;3.5
	RETLW	3	;3.6
	RETLW	0	;3.7
	RETLW	0	;3.8
	RETLW	0	;3.9
	RETLW	27	;4.0
	RETLW	23	;4.1
	RETLW	19	;4.2
	RETLW	15	;4.3
	RETLW	11	;4.4
	RETLW	7	;4.5
	RETLW	3	;4.6
	RETLW	0	;4.7
	RETLW	0	;4.8
	RETLW	0	;4.9
	RETLW	38	;5.0
	RETLW	31	;5.1
	RETLW	27	;5.2
	RETLW	23	;5.3
	RETLW	19	;5.4
	RETLW	15	;5.5
	RETLW	11	;5.6
	RETLW	7	;5.7
	RETLW	3	;5.8
	RETLW	0	;5.9
;------------------------　片側減速時の反対側補正値　-------
SSOKUDO2
	ADDWF	PC,1	;X
	RETLW	10	;0
	RETLW	15	;1
	RETLW	15	;2
	RETLW	10	;3
	RETLW	5	;4
	RETLW	0	;5


START
	CLRF	PORTB		;クリア PORTB
	BSF	STATUS,PG	;Change Page1
	CLRF	TRISB		;TRISB=0  All output
	MOVLW	B'01111'	;RA4のみ出力
	MOVWF	TRISA		;RA0-3は入力
	BCF	STATUS,PG	;Change Page0

;--------------音・発光の初期値 ----------------
	BSF	PORTB,7		;音のスイッチ off
        MOVLW	B'10000'	;RA4のLEDをOFF
	MOVWF	PORTA		;
	BSF	PORTB,5		;LED off

	MOVLW	1		;発光のタイミング設定クリア
	MOVWF	COUNT8

	MOVLW	1
	CALL	TIM90


;------------------ ＥＥＰＲＯＭ読込
	MOVLW	0		;EPPROMの0番地（先頭）のＤＡＴＡを読む
	MOVWF	EEADR		;
	BSF	STATUS,PG	;Change Page1
	BSF	EECON1,RD	;読出し開始
	BCF	STATUS,PG	;Change Page0
	MOVF	EEDATA,0
	MOVWF	CENTER3		;CENTER3=W	砲塔旋回サーボセンターの位置を記憶

	MOVLW	1		;EPPROMの1番地のＤＡＴＡを読む
	MOVWF	EEADR		;
	BSF	STATUS,PG	;Change Page1
	BSF	EECON1,RD	;読出し開始
	BCF	STATUS,PG	;Change Page0
	MOVF	EEDATA,0
	MOVWF	CENTER1		;CENTER1=W	アンプセンターの位置を記憶

	MOVLW	2		;EPPROMの2番地のＤＡＴＡを読む
	MOVWF	EEADR		;
	BSF	STATUS,PG	;Change Page1
	BSF	EECON1,RD	;読出し開始
	BCF	STATUS,PG	;Change Page0
	MOVF	EEDATA,0
	MOVWF	CENTER2		;CENTER2=W	アンプセンターの位置を記憶

;-------ＲＯＭ値のチェック（走行用アンプ）
	MOVLW	170		;
	SUBWF	CENTER1,0	;
	BTFSC	STATUS,0	;(CY=1) CENTER1>=170はLOOP00へ
	GOTO	LOOP00A		;
	MOVLW	130		;
	SUBWF	CENTER1,0	;
	BTFSS	STATUS,0	;(CY=0) CENTER1<120はLOOP00へ
	GOTO	LOOP00A		;
	GOTO	LOOP000A
LOOP00A
	MOVLW	150		;アンプのセンターを１５０（停止）に設定
	MOVWF	CENTER1

LOOP000A
	MOVLW	170		;
	SUBWF	CENTER2,0	;
	BTFSC	STATUS,0	;(CY=1) CENTER2>=170はLOOP00へ
	GOTO	LOOP00B		;
	MOVLW	130		;
	SUBWF	CENTER2,0	;
	BTFSS	STATUS,0	;(CY=0) CENTER2<120はLOOP00へ
	GOTO	LOOP00B		;
	GOTO	LOOP000B
LOOP00B
	MOVLW	150		;アンプのセンターを１５０（停止）に設定
	MOVWF	CENTER2

LOOP000B

;-------ＲＯＭ値のチェック(砲塔旋回サーボの中心)
	MOVLW	180		;
	SUBWF	CENTER3,0	;
	BTFSC	STATUS,0	;(CY=1) CENTER3>=180はLOOP00へ
	GOTO	LOOP00		;
	MOVLW	120		;
	SUBWF	CENTER3,0	;
	BTFSS	STATUS,0	;(CY=0) CENTER3<120はLOOP00へ
	GOTO	LOOP00		;
	GOTO	LOOP000
LOOP00
	MOVLW	150		;砲塔旋回値を１５０（停止）に設定
	MOVWF	CENTER3

LOOP000


;********走行用アンプ＆砲塔旋回サーボの停止位置設定（電源投入時、前進後進スティックが１番下の時に設定登録）

	MOVLW	1
	CALL	TIM90
	CALL	PULSOFF		;電源入れていきなり受け取るとノイズがあるかも...ちょっと待とう
	CALL	PULSIN2A	;2chパルス幅取得

	MOVLW	180		;前後スティックが180以上だったら設定開始
	SUBWF	PIN2,0		;
	BTFSS	STATUS,0	;(CY=0) PIN2<180はLOOP01へ
	GOTO	LOOP01		;

	BCF	PORTB,5		;LED on（設定中は機銃用ＬＥＤを点灯）
        MOVLW	B'00000'	;RA4のLEDもON
	MOVWF	PORTA		;

LOOP0
	CALL	PULSIN4A		;4chパルス幅取得
	CALL	PULSIN2A		;2chパルス幅取得
	CALL	PULSIN3A		;3chパルス幅取得
	MOVF	PIN2,0		;W=PIN2
	MOVWF	CENTER1		;CENTER1=W	センターの位置を記憶
	MOVF	PIN3,0		;W=PIN3
	MOVWF	CENTER2		;CENTER2=W	センターの位置を記憶

	CALL	PULSIN1A		;1chパルス幅取得

	MOVF	PIN4,0		;-------  プロポの左右スティック値を
	MOVWF	POUT4		;-------  そのまま砲塔旋回サーボへ出力
	BSF	PORTB,3		;PULS3 on
	MOVF	POUT4,0		;
	CALL	TIM25		;
	BCF	PORTB,3		;PULS off
;
	BSF	PORTB,0		;PULS1 on
	MOVF	CENTER1,0	;W=CENTER1
;	MOVLW	150		;アンプのセンター位置
	CALL	TIM25		;
	BCF	PORTB,0		;PULS off
;
	BSF	PORTB,1		;PULS2 on
	MOVF	CENTER2,0	;W=CENTER2
;	MOVF	150		;アンプのセンター位置
	CALL	TIM25		;
	BCF	PORTB,1		;PULS off

	CALL	PULSOFF

	MOVLW	120		;左右スティックが120以下だったら設定終了
	SUBWF	PIN1,0		;
	BTFSC	STATUS,0	;(CY=1) PIN1>=120はLOOP0へ
	GOTO	LOOP0		;

	BSF	PORTB,5		;LED off（機銃用のＬＥＤを消す）
        MOVLW	B'10000'	;RA4のLEDをOFF
	MOVWF	PORTA		;
	MOVF	PIN4,0		;W=PIN4
	MOVWF	CENTER3		;CENTER3=W	センターの位置を記憶

;-------- ＥＥＰＲＯＭ書き込み
	MOVWF	EEDATA		;EEDATA=W
	MOVLW	0		;
	CALL	EEPW

	MOVF	CENTER1,0	;W=CENTER1
	MOVWF	EEDATA		;EEDATA=W
	MOVLW	1		;
	CALL	EEPW

	MOVF	CENTER2,0	;W=CENTER2
	MOVWF	EEDATA		;EEDATA=W
	MOVLW	2		;
	CALL	EEPW


;---------砲身のデフォルト位置＆上下スピード
LOOP01
	MOVLW	150		;スイッチを入れたときの砲身のデフォルト角度設定
	MOVWF	POUT3		;

	MOVLW	2		;砲身上下のスピード0-5
	MOVWF	HSPEED		;
	MOVWF	COUNT3		;

;-----------ブローバック用サーボ停止位置 ------------
	MOVLW	200		;
	MOVWF	POUT5
	MOVLW	255		;
	MOVWF	COUNT4

;---------- デモ
DEMO01
	CALL	PULSIN1A		;1chパルス幅取得
	MOVLW	180		;左右スティックが180以上だったらＤＥＭＯ開始
	SUBWF	PIN1,0		;
	BTFSS	STATUS,0	;(CY=0) PIN1<180はLOOP1へ
	GOTO	LOOP1		;
DEMO02

	MOVLW	150
	CALL	JYOGE		;砲身上下

	MOVLW	5
	CALL	TIM90


	MOVLW	110
	CALL	JYOGE		;砲身上下

	MOVLW	5
	CALL	TIM90

	MOVLW	135
	CALL	JYOGE		;砲身上下

	MOVLW	6
	CALL	TIM90

	CALL	TAIHO		;大砲発射

	MOVLW	6
	CALL	SENKAIR		;砲塔右旋回

	MOVLW	6
	CALL	TIM90

	CALL	TAIHO		;大砲発射

	MOVLW	4
	CALL	TIM90

	MOVLW	5
	CALL	OTOSUB		;機銃音

	MOVLW	7
	CALL	TIM90


	MOVLW	20
	CALL	SENKAIL		;砲塔左旋回

	MOVLW	8
	CALL	TIM90

	MOVLW	30
	CALL	SENKAIR		;砲塔右旋回

	MOVLW	5
	CALL	TIM90

	MOVLW	3
	CALL	OTOSUB		;機銃音
	MOVLW	3
	CALL	TIM90
	MOVLW	5
	CALL	OTOSUB		;機銃音
	MOVLW	7

	MOVLW	3
	CALL	TIM90

	MOVLW	110
	CALL	JYOGE		;砲身上下

	MOVLW	5
	CALL	TIM90
	CALL	TAIHO		;大砲発射
	MOVLW	5
	CALL	TIM90

	MOVLW	135
	CALL	JYOGE		;砲身上下
	MOVLW	7
	CALL	TIM90

	MOVLW	30
	CALL	SENKAIR		;砲塔右旋回
	MOVLW	7
	CALL	TIM90


	GOTO	DEMO02		;


;-------------------メインルーチン -------------
LOOP1

	CALL	PULSIN1		;1chパルス幅取得
	CALL	PULSIN2		;2chパルス幅取得
	CALL	PULSOUTSUB	;受信機からパルスを受け取る時間が長すぎるので、途中でアンプ出力する
	CALL	PULSIN3		;3chパルス幅取得
	CALL	PULSIN4		;4chパルス幅取得

	MOVF	PIN2,0
	MOVWF	POUT1
	MOVWF	POUT2


	MOVF	CENTER3,0	;W=CENTER3
	MOVWF	POUT4		;POUT4=W	砲塔旋回サーボを停止


;--------停止中

	MOVLW	152		;前後スティックが153以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=152はNEXT51へ
	GOTO	NEXT51
	MOVLW	148		;前後スティックが147以上だったら停止
	SUBWF	PIN2,0		;
	BTFSS	STATUS,0	;(CY=0) PIN2<147はNEXT51へ
	GOTO	NEXT51
;	MOVLW	150		;左右中間(停止)に
	MOVF	CENTER1,0	;W=CENTER1
	MOVWF	POUT1
	MOVF	CENTER2,0	;W=CENTER2
	MOVWF	POUT2

;-----------------　音　---------------
	MOVLW	115		;1chスティックが115以下だったら
	SUBWF	PIN1,0		;
	BTFSC	STATUS,0	;(CY=1) PIN1>=115はOTO10へ
	GOTO	OTO10		;

	BSF	STATUS,PG	;Change Page1
	BSF	TRISB,6		;RB6を入力に切替
	BCF	STATUS,PG	;Change Page0


	BCF	PORTB,7		;音のＳＷ on(機関銃音)

	DECFSZ	COUNT8,1	;COUNT8が0の時だけＬＥＤ点ける
	GOTO	OTO80
	BCF	PORTB,5		;LED on
	MOVLW	3		;発光のタイミング設定 1-10
	MOVWF	COUNT8

	CALL	PULSOFF		;発光の間隔の時間稼ぎ
	CALL	PULSOFF
	CALL	PULSOFF

	GOTO	OTO80		;

OTO10
	MOVLW	185		;1chスティックが185以上だったら
	SUBWF	PIN1,0		;
	BTFSS	STATUS,0	;(CY=0) PIN1<185はOTO20へ
	GOTO	OTO20		;

	MOVLW	255		;COUNT4<>255だったら
	SUBWF	COUNT4,0	;
	BTFSS	STATUS,2	;(Z=0) COUNT4<>255
	GOTO	OTO80

        MOVLW	B'00000'	;RA4のLEDをON
	MOVWF	PORTA		;

	BSF	STATUS,PG	;Change Page1
	BCF	TRISB,6		;RB6を出力に切替
	BCF	STATUS,PG	;Change Page0

	BSF	PORTB,6		;PULS6 on（音切り換え）
	CALL	TIM20		;ちょっと待つ
	BCF	PORTB,7		;音のＳＷ on（大砲音）

;-----------  砲身後退　-----------
	MOVLW	90		;砲身後退サーボの値を９０にして
	MOVWF	POUT5		;砲身を一挙に後退
	MOVLW	30		;後退した後の一瞬の停止時間の設定
	MOVWF	COUNT4		;10～100（100で停止無し）

;----------- 車体の揺れ？？ --------

	MOVLW	5		;バックの時間
	CALL	BACKSP
	CALL	PULSOFF
	CALL	PULSOFF
	MOVLW	8		;前進の時間
	CALL	TOPSP

	CALL	PULSOFF

	BSF	PORTB,0		;PULS1 on
	MOVF	CENTER1,0	;W=CENTER1
;	MOVLW	150		;停止位置にに戻す
	CALL	TIM25
	BCF	PORTB,0		;PULS off

	BSF	PORTB,1		;PULS2 on
	MOVF	CENTER2,0	;W=CENTER1
;	MOVLW	150		;停止位置にに戻す
	CALL	TIM25
	BCF	PORTB,1		;PULS off

	GOTO	OTO80		;

OTO20
	BSF	PORTB,7		;音のＳＷ off
        MOVLW	B'10000'	;RA4のLEDをOFF
	MOVWF	PORTA		;制御実行

OTO80

	GOTO	PULSOUT
NEXT51
	BSF	PORTB,7		;音のＳＷ off
;--------超信地旋回左
	MOVLW	109		;左右スティックが110以下だったら
	SUBWF	PIN1,0		;
	BTFSC	STATUS,0	;(CY=1) PIN1>=109はNEXT2へ
	GOTO	NEXT2		;
	MOVLW	210		;
	MOVWF	POUT1		;逆転速度＝210-（速度－90）
	MOVLW	90		;
	SUBWF	PIN2,0		;(W=PIN2-90)
	SUBWF	POUT1,1		;(POUT1＝210-W)
	GOTO	PULSOUT
NEXT2
;--------超信地旋回右
	MOVLW	191		;左右スティックが191以上だったら
	SUBWF	PIN1,0		;
	BTFSS	STATUS,0	;(CY=0) PIN1<191はNEXT3へ
	GOTO	NEXT3		;
	MOVLW	210		;
	MOVWF	POUT2		;逆転速度＝210-（速度－90）
	MOVLW	90		;
	SUBWF	PIN2,0		;(W=PIN2-90)
	SUBWF	POUT2,1		;(POUT2＝210-W)
	GOTO	PULSOUT
NEXT3
;--------信地旋回左
;	MOVLW	114		;左右スティックが115以下だったら
;	SUBWF	PIN1,0		;
;	BTFSC	STATUS,0	;(CY=1) PIN1>=114はNEXT4へ
;	GOTO	NEXT4		;
;	MOVF	CENTER1,0	;W=CENTER1
;	MOVWF	POUT1		;速度＝150(片側停止)
;	GOTO	PULSOUT
NEXT4
;--------信地旋回右
;	MOVLW	185		;左右スティックが185以上だったら
;	SUBWF	PIN1,0		;
;	BTFSS	STATUS,0	;(CY=0) PIN1<185はNEXT5へ
;	GOTO	NEXT5		;
;	MOVF	CENTER2,0	;W=CENTER2
;	MOVWF	POUT2		;速度＝150(片側停止)
;	GOTO	PULSOUT
NEXT5

;--------左旋回
	MOVLW	148		;左右スティックが147以下だったら
	SUBWF	PIN1,0		;
	BTFSC	STATUS,0	;(CY=1) PIN1>=148はNEXT7へ
	GOTO	NEXT7		;
;--------前進
	MOVLW	150		;前後スティックが150以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=150はNEXT62へ
	GOTO	NEXT62		;

	MOVF	POUT1,0		;W=POUT1
	SUBLW	150		;W=150-速度
	CALL	WARU10		;((150-速度)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVF	PIN1,0		;W=PIN1
	SUBLW	150		;150-角度
	CALL	WARU5		;(150-角度)÷5
	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	KEISAN3		;KEISAN3=W
	MOVF	CENTER1,0	;W=CENTER1
;	MOVLW	150		;W=150
	MOVWF	POUT1		;POUT1=W
	MOVF	KEISAN3,0	;W=KEISAN3
	SUBWF	POUT1,1		;POUT1=POUT1-W

	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
	SUBWF	POUT2,1		;POUT2=POUT2-W

	GOTO	PULSOUT

NEXT62
;--------後進
	MOVLW	150		;W=150
	SUBWF	POUT1,0		;W=速度-150

	CALL	WARU10		;((速度-150)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVF	PIN1,0
	SUBLW	150		;150-角度
	CALL	WARU5		;(150-角度)÷5
	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	POUT1		;POUT1=W
	MOVF	CENTER1,0	;W=CENTER1
;	MOVLW	150		;W=150
	ADDWF	POUT1,1		;POUT1=POUT1+W

	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
	ADDWF	POUT2,1		;POUT2=POUT2+W

	GOTO	PULSOUT

NEXT7

;--------右旋回
	MOVLW	153		;左右スティックが153以上だったら
	SUBWF	PIN1,0		;
	BTFSS	STATUS,0	;(CY=0) PIN1<153はNEXT8へ
	GOTO	NEXT8		;

;--------前進
	MOVLW	150		;前後スティックが150以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=150はNEXT72へ
	GOTO	NEXT72		;

	MOVF	POUT2,0
	SUBLW	150		;150-速度

	CALL	WARU10		;((150-速度)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVLW	150
	SUBWF	PIN1,0		;角度-150
	CALL	WARU5		;(角度-150)÷5
	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	KEISAN3		;KEISAN3=W
	MOVF	CENTER2,0	;W=CENTER2
;	MOVLW	150		;W=150
	MOVWF	POUT2		;POUT2=W
	MOVF	KEISAN3,0	;W=KEISAN3
	SUBWF	POUT2,1		;POUT2=POUT2-W

	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
	SUBWF	POUT1,1		;POUT1=POUT1-W

	GOTO	PULSOUT

NEXT72
;--------後進
	MOVLW	150		;W=150
	SUBWF	POUT1,0		;速度-150

	CALL	WARU10		;((速度-150)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVLW	150
	SUBWF	PIN1,0		;角度-150
	CALL	WARU5		;(角度-150)÷5

	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	POUT2		;POUT2=W
	MOVF	CENTER2,0	;W=CENTER2
;	MOVLW	150		;W=150
	ADDWF	POUT2,1		;POUT2=POUT2+W

	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
	ADDWF	POUT1,1		;POUT1=POUT1+W

	GOTO	PULSOUT

NEXT8

PULSOUT
;--------- 走行用パルス出力
	CALL	PULSOUTSUB
;--------- 砲塔旋回

	MOVLW	120		;左右旋回スティックが120以下だったら
	SUBWF	PIN4,0		;
	BTFSC	STATUS,0	;(CY=1) PIN4>=120はNEXT52へ
	GOTO	NEXT52		;


	MOVLW	8		;
	SUBWF	CENTER3,0	;POUT4=CENTER3-8
	MOVWF	POUT4		;
	GOTO	NEXT53		;

NEXT52

	MOVLW	180		;左右旋回スティックが180以上だったら
	SUBWF	PIN4,0		;
	BTFSS	STATUS,0	;(CY=0) PIN4<180はNEXT54へ
	GOTO	NEXT54

	MOVLW	8		;
	ADDWF	CENTER3,0	;POUT4=CENTER3+8
	MOVWF	POUT4		;
NEXT53

	BSF	PORTB,3		;PULS4 on
	MOVF	POUT4,0
	CALL	TIM25
	BCF	PORTB,3		;PULS off
NEXT54

;------------　　砲身を戻す処理
	MOVLW	250		;250以上だったら
	SUBWF	COUNT4,0	;
	BTFSS	STATUS,0	;(CY=0) COUNT4<250は
	GOTO	PULSOUT31
	MOVLW	255		;
	MOVWF	COUNT4		;COUNT4=255
	GOTO	PULSOUT32
PULSOUT31
	MOVLW	4		;砲身を戻す時のスピード(1-5)
	ADDWF	COUNT4,1	;COUNT4=COUNT4+4
PULSOUT32
	MOVLW	200		;200以上だったら
	SUBWF	COUNT4,0	;
	BTFSS	STATUS,0	;(CY=0) COUNT4<200は
	GOTO	PULSOUT30	;
	MOVLW	200		;
	MOVWF	POUT5		;POUT5=200
	GOTO	PULSOUT40	;

PULSOUT30
	MOVLW	100		;100以上だったら
	SUBWF	COUNT4,0	;
	BTFSS	STATUS,0	;(CY=0) COUNT4<100は
	GOTO	PULSOUT40	;

	MOVF	COUNT4,0	;W=COUNT4
	MOVWF	POUT5		;POUT5=W

PULSOUT40
	BSF	PORTB,4		;PULS5 on
	MOVF	POUT5,0
	CALL	TIM25
	BCF	PORTB,4		;PULS off

;	CALL	PULSOFF

;------------砲身上下サーボ
	DECFSZ	COUNT3,1		;COUNT3=COUNT3-1
	GOTO	PULSOUT10		;COUNT3>0はサーボはそのまま

	MOVF	HSPEED,0	;COUNT3＝HSPEED(砲身上下のスピード)
	MOVWF	COUNT3		;


	MOVLW	180		;砲身上下スティックが180以上だったら
	SUBWF	PIN3,0		;
	BTFSS	STATUS,0	;(CY=0) PIN3<180はPULSOUT3へ
	GOTO	PULSOUT3	;


	INCF	POUT3,1		;POUT3=POUT3+1

	MOVLW	170		;砲身上下サーボがすでに200以上だったら
	SUBWF	POUT3,0		;
	BTFSS	STATUS,0	;(CY=0) POUT3<200はPULSOUT10へ
	GOTO	PULSOUT10	;

	MOVLW	170		;砲身上下サーボを200に固定
	MOVWF	POUT3		;POUT3=200
	GOTO	PULSOUT10

PULSOUT3
	MOVLW	120		;砲身上下スティックが120以下だったら
	SUBWF	PIN3,0		;
	BTFSC	STATUS,0	;(CY=1) PIN3>=120はPULSOUT10へ
	GOTO	PULSOUT10	;

	DECF	POUT3,1		;POUT3=POUT3-1

	MOVLW	100		;砲身上下サーボがすでに100以下だったら
	SUBWF	POUT3,0		;
	BTFSC	STATUS,0	;(CY=1) POUT3>=100はPULSOUT10へ
	GOTO	PULSOUT10	;

	MOVLW	100		;砲身上下サーボを100に固定
	MOVWF	POUT3		;POUT3=100

PULSOUT10

	BSF	PORTB,2		;PULS3 on
	MOVF	POUT3,0
	CALL	TIM25
	BCF	PORTB,2		;PULS3 off

;	CALL	PULSOFF

	BSF	PORTB,5		;LED off

	GOTO	LOOP1

;==================走行用２アンプ出力のサブルーチン
PULSOUTSUB
;--------停止中はパルスを出さない
	MOVLW	154		;前後スティックが154以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=154はNEXT51へ
	GOTO	PULSOUTSUB1	;
	MOVLW	146		;前後スティックが146以上だったら停止
	SUBWF	PIN2,0		;
	BTFSS	STATUS,0	;(CY=0) PIN2<146はNEXT51へ
	GOTO	PULSOUTSUB1	;
	RETURN
PULSOUTSUB1
	BSF	PORTB,0		;PULS1 on
	MOVF	POUT1,0
	CALL	TIM25
	BCF	PORTB,0		;PULS off

	CALL	PULSOFF

	BSF	PORTB,1		;PULS2 on
	MOVF	POUT2,0
	CALL	TIM25
	BCF	PORTB,1		;PULS off
	RETURN

;============================  機関銃音のサブルーチン
OTOSUB
	MOVWF	COUNT11		;
	BSF	STATUS,PG	;Change Page1
	BSF	TRISB,6		;RB6を入力に切替
	BCF	STATUS,PG	;Change Page0

	BCF	PORTB,7		;音のＳＷ on(機関銃音)

OTOSUB1
	BCF	PORTB,5		;LED on
	MOVLW	1	
	CALL	TIM90
	BSF	PORTB,5		;LED off
	MOVLW	1
	CALL	TIM90
	DECFSZ	COUNT11,1	;COUNT11が0になるまで繰り返す
	GOTO	OTOSUB1

	BSF	PORTB,7		;音のＳＷ off
	RETURN			;

;============================  大砲発射のサブルーチン
TAIHO

        MOVLW	B'00000'	;RA4のLEDをON
	MOVWF	PORTA		;制御実行
	MOVLW	3
	CALL	TIM90

	BSF	STATUS,PG	;Change Page1
	BCF	TRISB,6		;RB6を出力に切替
	BCF	STATUS,PG	;Change Page0

	BSF	PORTB,6		;on（音切り換え）
	CALL	TIM20		;ちょっと待つ
	BCF	PORTB,7		;音のＳＷ on（大砲音）


;-----------  砲身後退
	MOVLW	90		;砲身後退サーボの値を９０にして
	MOVWF	POUT5		;砲身を一挙に後退
	MOVLW	70		;後退した後の一瞬の停止時間の設定
	MOVWF	COUNT4		;80～100（100で停止無し）
	BSF	PORTB,4		;PULS5 on
	MOVF	POUT5,0
	CALL	TIM25
	BCF	PORTB,4		;PULS off

	CALL	PULSOFF
	CALL	PULSOFF
	CALL	PULSOFF
	CALL	PULSOFF

;----------- 車体の揺れ
	MOVLW	6		;バックの時間
	CALL	BACKSP
	CALL	PULSOFF
	CALL	PULSOFF
	MOVLW	7		;前進の時間
	CALL	TOPSP

	CALL	PULSOFF

	BSF	PORTB,0		;PULS1 on
	MOVLW	150		;停止位置にに戻す
	CALL	TIM25
	BCF	PORTB,0		;PULS off

	BSF	PORTB,1		;PULS2 on
	MOVLW	150		;停止位置にに戻す
	CALL	TIM25
	BCF	PORTB,1		;PULS off

        MOVLW	B'10000'	;RA4のLEDをOFF制御
	MOVWF	PORTA		;


;------------　　砲身を戻す処理
TAIHO01
	MOVLW	201		;200以上だったら
	SUBWF	COUNT4,0	;
	BTFSS	STATUS,0	;(CY=0) COUNT4<201は
	GOTO	TAIHO02
	MOVLW	255		;
	MOVWF	COUNT4		;COUNT4=255

	MOVLW	20
	CALL	TIM90

	BSF	PORTB,7		;PULS off（大砲音）

	RETURN

TAIHO02
	MOVLW	1		;
	ADDWF	COUNT4,1	;COUNT4=COUNT4+1

TAIHO03
	MOVLW	100		;100以上だったら
	SUBWF	COUNT4,0	;
	BTFSS	STATUS,0	;(CY=0) COUNT4<100は
	GOTO	TAIHO04	;

	MOVF	COUNT4,0	;W=COUNT4
	MOVWF	POUT5		;POUT5=W

TAIHO04
	CALL	PULSOFF
	CALL	PULSOFF
	BSF	PORTB,4		;PULS5 on
	MOVF	POUT5,0
	CALL	TIM25
	BCF	PORTB,4		;PULS off

	CALL	PULSOFF
	CALL	PULSOFF
	CALL	PULSOFF
	GOTO	TAIHO01

;====================== 砲塔旋回 右 =====================
SENKAIR
	MOVWF	COUNT11		;

	MOVLW	2		;
	SUBWF	CENTER3,0	;POUT4=CENTER3-2
	MOVWF	POUT4		;
	GOTO	SENKAI02
;====================== 砲塔旋回 左 =====================
SENKAIL
	MOVWF	COUNT11		;

	MOVLW	2		;
	ADDWF	CENTER3,0	;POUT4=CENTER3+2
	MOVWF	POUT4		;
	GOTO	SENKAI02

SENKAI02
	MOVLW	20
	MOVWF	COUNT9
SENKAI03
	CALL	SENKAI
	DECFSZ	COUNT9,1	;COUNT9が0になるまで繰り返す
	GOTO	SENKAI03

	DECFSZ	COUNT11,1	;COUNT11が0になるまで繰り返す
	GOTO	SENKAI02

	MOVF	CENTER3,0	;W=CENTER3
	MOVWF	POUT4		;POUT4=W	砲塔旋回サーボを停止
	CALL	SENKAI
	RETURN

SENKAI
	CALL	PULSOFF
	CALL	PULSOFF
	BSF	PORTB,3		;PULS4 on
	MOVF	POUT4,0
	CALL	TIM25
	BCF	PORTB,3		;PULS off
	CALL	PULSOFF
	CALL	PULSOFF
	CALL	PULSOFF
	RETURN

;====================== 砲身上下 =====================
JYOGE
	MOVWF	COUNT11
	MOVLW	10
	MOVWF	COUNT10

JYOGE01
	MOVF	COUNT11,0
	SUBWF	POUT3,0
	BTFSS	STATUS,0	;(CY=0) POUT3<Wは
	GOTO	JYOGE02

	MOVF	COUNT11,0
	SUBWF	POUT3,0
	BTFSC	STATUS,2	;(Z=1) POUT3=Wは
	RETURN

	DECFSZ	COUNT10,1	;COUNT10が0になるまで繰り返す
	GOTO	JYOGE04

	MOVLW	1
	SUBWF	POUT3,1		;POUT3=POUT3-1
	MOVLW	10
	MOVWF	COUNT10
	GOTO	JYOGE04

JYOGE02
	DECFSZ	COUNT10,1	;COUNT10が0になるまで繰り返す
	GOTO	JYOGE04

	MOVLW	1		;
	ADDWF	POUT3,1		;POUT3=POUT3+1
	MOVLW	10
	MOVWF	COUNT10


JYOGE04
	BSF	PORTB,2		;PULS3 on
	MOVF	POUT3,0
	CALL	TIM25
	BCF	PORTB,2		;PULS off
	CALL	PULSOFF
	CALL	PULSOFF
	CALL	PULSOFF
	CALL	PULSOFF
	GOTO	JYOGE01


;***********　Ｗ÷５＝Ｗ
WARU5
	MOVWF	KEISAN1		;Ｗ=KEISAN1
	MOVLW	0		;
	MOVWF	KEISAN2		;カウンター初期化
	MOVF	KEISAN1,0	;W=KEISAN1
	SUBLW	4
	BTFSS	STATUS,0	;W>4
	GOTO	WARU51
	RETURN
WARU51
	MOVLW	5		;
	SUBWF	KEISAN1,1
	BTFSS	STATUS,0	;CY=0　で終了
	RETURN
	INCF	KEISAN2,1	;KEISAN2=KEISAN2+1
	GOTO	WARU51

;***********　(Ｗ÷１０)×10＝KEISAN2
WARU10
	MOVWF	KEISAN1		;KEISAN1=W
	MOVLW	0		;
	MOVWF	KEISAN2		;カウンター初期化
	MOVF	KEISAN1,0	;W=KEISAN1
	SUBLW	9
	BTFSS	STATUS,0	;W>9
	GOTO	WARU101
	MOVLW	0		;
	MOVWF	SOKUDO		;速度＋分を0
	RETURN

WARU101
	MOVLW	10		;
	SUBWF	KEISAN1,1
	BTFSS	STATUS,0	;CY=0　で終了
	GOTO	KAKEL5
	INCF	KEISAN2,1	;KEISAN2=KEISAN2+1
	GOTO	WARU101

;***********　KEISAN2×10＝W
KAKEL5
	MOVF	KEISAN2,0	;W=KEISAN2
	CALL	SSOKUDO2
	MOVWF	SOKUDO		;SOKUDO=W

	MOVLW	0		;
	MOVWF	KEISAN1		;カウンター初期化
KAKELU51
	DECFSZ	KEISAN2,1	;KEISAN2=KEISAN2-1
	GOTO	KAKELU52	;KEISAN2が0になるまで繰り返し
	MOVF	KEISAN1,0	;W=KEISAN1
	RETURN
KAKELU52
	MOVLW	10		;
	ADDWF	KEISAN1,1		;KEISAN1=KEISAN1+W
	GOTO	KAKELU51


;-------------  20サイクルタイマー（実際は19サイクル）
TIM20
	GOTO	$+1	;2
	GOTO	$+1	;+2=4
	GOTO	$+1	;+2=6
	GOTO	$+1	;+2=8
	GOTO	$+1	;+2=10
	GOTO	$+1	;+2=12
	GOTO	$+1	;+2=14
	GOTO	$+1	;+2=16
	NOP		;+1=17
	RETURN		;+2=19

;-------------  Ｗレジスタ分のカウントタイマー(1カウント=25サイクル)×Ｗ
TIM25
	MOVWF	COUNT1		;1+1=2
TIM26
	CALL	TIM20		;19+2=21
	NOP			;+1=22
	DECFSZ	COUNT1,1	;+1=23
	GOTO	TIM26		;+2=25
	RETURN			;+1+(W*25)+2-1

;-----------パルスとパルスの間の空き時間-----------------
PULSOFF
	MOVLW	150
	CALL	TIM25		;
;	MOVLW	255
;	CALL	TIM25		;
	RETURN

;-------------  時間稼ぎ(1/4秒×Ｗ)
TIM90
	MOVWF	COUNT10		;
TIM91
	MOVLW	50
	MOVWF	COUNT9		;
TIM92
	MOVLW	255
	CALL	TIM25		;
	DECFSZ	COUNT9,1	;
	GOTO	TIM92		;
	DECFSZ	COUNT10,1	;
	GOTO	TIM91		;
	RETURN			;

;-------------  揺れ（一瞬ＴＯＰに）
TOPSP
	MOVWF	COUNT11		;
TOPSP1
	BSF	PORTB,0		;PULS1 on
	MOVLW	200		;
	CALL	TIM25
	BCF	PORTB,0		;PULS off

	BSF	PORTB,1		;PULS2 on
	MOVLW	200		;
	CALL	TIM25
	BCF	PORTB,1		;PULS off

	CALL	PULSOFF
	CALL	PULSOFF
	DECFSZ	COUNT11,1	;COUNT11が0になるまで繰り返す
	GOTO	TOPSP1		;
	RETURN			;

;-------------  揺れ（一瞬バックに）
BACKSP
	MOVWF	COUNT11		;
BACKSP1
	BSF	PORTB,0		;PULS1 on
	MOVLW	100		;
	CALL	TIM25
	BCF	PORTB,0		;PULS off

	BSF	PORTB,1		;PULS2 on
	MOVLW	100		;
	CALL	TIM25
	BCF	PORTB,1		;PULS off

	CALL	PULSOFF
	CALL	PULSOFF
	DECFSZ	COUNT11,1	;COUNT11が0になるまで繰り返す
	GOTO	BACKSP1		;
	RETURN			;

;-------- ＥＥＰＲＯＭ書き込み
EEPW
	MOVWF	EEADR		;
	BSF	STATUS,PG	;Change Page1
	BSF	EECON1,WREN	;EECON1のWREN=1(書込許可)
	MOVLW	H'55'
	MOVWF	EECON2		;書込開始
	MOVLW	H'AA'
	MOVWF	EECON2
	BSF	EECON1,WR	;
WR_LP
	BTFSC	EECON1,WR	;書込終了チェック
	GOTO	WR_LP
	BCF	STATUS,PG	;Change Page0
	RETURN
;-----------1CHパルス幅測定（PIN1）前進・後進のスティックの信号チェック-------
PULSIN1A
	BTFSS	PORTA,0		;OFF の時
	GOTO	PULSIN1		;入力開始
	CALL	TIM20
	GOTO	PULSIN1A	;次の信号まで待つ
;-----------1CHパルス幅測定（PIN1）左右のステック-----------
PULSIN1
	BTFSS	PORTA,0		;OFF の時
	GOTO	PULSIN1		;入力待ちループ
	MOVLW	0		;
	MOVWF	PIN1		;カウンター初期化
PULSIN11
	CALL	TIM20		;20サイクル待ち	(19+2)
	INCF	PIN1,1		;PIN1=PIN1+1	(22)
	BTFSC	PORTA,0		;ＯＮの時は	(23)
	GOTO	PULSIN11	;カウント継続	(25)

	MOVLW	90		;カウントが90以下だったら
	SUBWF	PIN1,0		;カウントしなおし！
	BTFSS	STATUS,0	;(CY=0) PIN1<90
	GOTO	PULSIN1		;
	RETURN
;-----------2CHパルス幅測定（PIN2）前進・後進のスティックの信号チェック-------
PULSIN2A
	BTFSS	PORTA,1		;OFF の時
	GOTO	PULSIN2		;入力開始
	CALL	TIM20
	GOTO	PULSIN2A	;次の信号まで待つ

;-----------2CHパルス幅測定（PIN2）前進・後進のスティック-----------
PULSIN2
	BTFSS	PORTA,1		;OFF の時
	GOTO	PULSIN2		;入力待ちループ
	MOVLW	0		;
	MOVWF	PIN2		;カウンター初期化
PULSIN21
	CALL	TIM20		;20サイクル待ち
	INCF	PIN2,1		;PIN1=PIN1+1
	BTFSC	PORTA,1		;ＯＮの時は、
	GOTO	PULSIN21	;カウント継続

	MOVLW	90		;カウントが90以下だったら
	SUBWF	PIN2,0		;カウントしなおし！
	BTFSS	STATUS,0	;(CY=0) PIN2<90
	GOTO	PULSIN2		;
	RETURN
;-----------3CHパルス幅測定（PIN3）前進・後進のスティックの信号チェック-------
PULSIN3A
	BTFSS	PORTA,2		;OFF の時
	GOTO	PULSIN3		;入力開始
	CALL	TIM20
	GOTO	PULSIN3A	;次の信号まで待つ

;-----------3CHパルス幅測定（PIN3）砲身上下用-----------
PULSIN3
	BTFSS	PORTA,2		;OFF の時
	GOTO	PULSIN3		;入力待ちループ
	MOVLW	0		;
	MOVWF	PIN3		;カウンター初期化
PULSIN31
	CALL	TIM20		;20サイクル待ち
	INCF	PIN3,1		;PIN3=PIN3+1
	BTFSC	PORTA,2		;ＯＮの時は、
	GOTO	PULSIN31	;カウント継続

	MOVLW	70		;カウントが70以下だったら
	SUBWF	PIN3,0		;カウントしなおし！
	BTFSS	STATUS,0	;(CY=0) PIN3<70
	GOTO	PULSIN3		;
	RETURN
;-----------4CHパルス幅測定（PIN4）前進・後進のスティックの信号チェック-------
PULSIN4A
	BTFSS	PORTA,3		;OFF の時
	GOTO	PULSIN4		;入力開始
	CALL	TIM20
	GOTO	PULSIN4A	;次の信号まで待つ

;-----------4CHパルス幅測定（PIN4）砲塔旋回用-----------
PULSIN4
	BTFSS	PORTA,3		;OFF の時
	GOTO	PULSIN4		;入力待ちループ
	MOVLW	0		;
	MOVWF	PIN4		;カウンター初期化
PULSIN41
	CALL	TIM20		;20サイクル待ち
	INCF	PIN4,1		;PIN4=PIN4+1
	BTFSC	PORTA,3		;ＯＮの時は、
	GOTO	PULSIN41	;カウント継続

	MOVLW	70		;カウントが70以下だったら
	SUBWF	PIN4,0		;カウントしなおし！
	BTFSS	STATUS,0	;(CY=0) PIN4<70
	GOTO	PULSIN4		;
	RETURN


	END
